Zitierformen

Auf dieser Seite können Sie ergänzend zu den in Litlink bereits eingebauten Zitierformen zusätzliche, von Ihnen programmierte neue Zit-Formen vorschlagen und herunterladen (dazu müssen Sie angemeldet sein). Wenn diese Zitierformen in die aktuelle Version von Litlink übernommen worden sind, werden sie aus dieser Liste wieder entfernt.

Übrigens…: Neue Zit-Formen für die Module Bilder, AV-Medien und Webseiten sowie Ereignisse, Orte und Objekte sind sehr willkommen!

Titel:

Historisches Seminar UZH korrigiert für 4.5

Beschreibung:

Historisches Seminar UZH Stefan Keller, 25.10.2010 Korrigiert für Litlink 4.5, Nicolaus Busch 09/2013

Autor:

Stefan Keller

Beispiel:

Connolly, James: Labour in Irish History, in: Ders.: Collected Works, Volume One, Dublin 1987, S. 118-289 [Collected Works in Two Volumes].

Getestet:

v4.5

Erstellt:

05.09.2013 08:43 / nicolausbusch

Letzte Änderung:

05.09.2013 08:43 / nicolausbusch


[ Kopieren ]

Berechnung:

/* Historisches Seminar UZH */
/* Stefan Keller, 25.10.2010 */
/* korrigiert für v4.5 N. Busch, 05.09.2013 */

Let(
[$Periodikum =
Case( DGlobals::d_SigleBenutzen_ng = 1 and not IsEmpty( DTitel.Periodikum::d_Sigle_t );
DTitel.Periodikum::d_Sigle_t;
DTitel.Periodikum::d_Titel_t );

$HerausgeberStatus =
Case( IsEmpty( d_HerausgeberName_t) and IsEmpty(d_Körperschaft_t) and d_Herausgeber_n <> 1 ; 0;
IsEmpty( d_HerausgeberName_t) and d_Herausgeber_n = 1 ; 1 ;
/* Autor ist Hg. */
not IsEmpty( d_HerausgeberName_t) and IsEmpty(d_AutorNachname_t); 2;
/* Kein Autor, aber Hg. */
not IsEmpty( d_HerausgeberName_t) and not IsEmpty(d_AutorNachname_t); 3;
/* Autor und separater Hg. */
not IsEmpty( d_Körperschaft_t) and not IsEmpty(d_AutorNachname_t); 4;
/* Autor und Körperschaft als Hg. */
not IsEmpty( d_Körperschaft_t) and IsEmpty(d_AutorNachname_t); 5);
/* Kein Autor, Körperschaft als Hg. */

$AutorPerson =

Trim( d_AutorNachname_t & Case( not IsEmpty( d_AutorVorname_t ) ; ", " &
d_AutorVorname_t ) & xcalc_Pseudonym_ctu ) ;

$Coautoren =

Trim(Case(
not IsEmpty( xCalc_NamenCoautorenUnsortiert_ctu) ;
DGlobals::d_Coautortrenner_tg & xCalc_NamenCoautorenUnsortiert_ctu ;
not IsEmpty( d_CoAutoren_t ) ;
"/" & d_CoAutoren_t
)) ;

$CoautorenSB =

Trim(Case(
not IsEmpty( DTitel.Titel.Sammelband::xCalc_NamenCoautorenUnsortiert_ctu) ;
DGlobals::d_Coautortrenner_tg & DTitel.Titel.Sammelband::xCalc_NamenCoautorenUnsortiert_ctu ;
not IsEmpty( DTitel.Titel.Sammelband::d_CoAutoren_t ) ;
", " & DTitel.Titel.Sammelband::d_CoAutoren_t
));

$Autor =
Case(
$Herausgeberstatus = 0;
$Autorperson &
$Coautoren;

$Herausgeberstatus = 1;
$Autorperson &
$Coautoren &
" (" & DGlobals::d_HerausgeberKuerzel_tg & ")" ;

$Herausgeberstatus = 2;
d_HerausgeberName_t & " (" & DGlobals::d_HerausgeberKuerzel_tg & ")" ;

$Herausgeberstatus = 3;
$Autorperson &
$Coautoren ;

$Herausgeberstatus = 4;
$Autorperson &
$Coautoren ;

$Herausgeberstatus = 5;
d_Körperschaft_t & " (" & DGlobals::d_HerausgeberKuerzel_tg & ")"
;
) // end case
]
;
Case(
d_Datentyp2_t = "Artikel";

// Zitform für Artikel in Zeitungen, Zeitschriften

Trim(
$Autor &
": " & d_Titel_t & ", in: " &
$Periodikum &
Case(
not IsEmpty( d_AusgabeVol_t ) ;
/* Wenn AusgabeVol nicht leer ist ... */
" " & d_AusgabeVol_t &
Case( not IsEmpty( d_Datierung_t ) ; ", " & d_Datierung_t ) ;
/* Wenn AUCH Datierung nicht leer ist */
Case(not IsEmpty(d_Datierung_t) ;
/* Wenn AusgabeVol leer ist, aber nicht Datierung */
", " & d_Datierung_t )
) // End Case
&
Case( not IsEmpty( d_AusgabeNr_t ); ", Nr. " & d_AusgabeNr_t ) &
Case( not IsEmpty( d_AusgabeSeite_t) ; ", S. " & d_AusgabeSeite_t )
) // End trim
;
d_Datentyp2_t = "Aufsatz";

// Zitform für Aufsätze in Sammelbänden

Trim(
$Autor &
": " & d_Titel_t & ", in: " &
Case(
DTitel::_fk_Autor_ct <> DTitel.Titel.Sammelband::_fk_Autor_ct;
DTitel.Titel.Sammelband::xCalc_NameAutorKomplett_cti& $CoautorenSB;
/* Haben Aufsatz und Sammelband verschiedene Autoren, beide vollständig nennen */
not isempty( DTitel::xCalc_NamenCoautorenNV_ctu) and DTitel::xCalc_NamenCoautorenNV_ctu =
DTitel.Titel.Sammelband::xCalc_NamenCoautorenNV_ctu ;
"Dies." ;
/* Gleiche Autoren und gleiche Coautoren, dann "dies." */
DTitel.Autor::d_Geschlecht_t = "f";
"Dies." & $CoautorenSB;
/* Autorin, dann "dies." */
"Ders." & $CoautorenSB ) &
/* Gleicher Autor, dann "ders." */

Case( DTitel.Titel.Sammelband::d_Herausgeber_n = 1 ; " (" &
DGlobals::d_HerausgeberKuerzel_tg & "): "; ": " ) &
DTitel.Titel.Sammelband::d_Titel_t & ", " &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_Ort_t ); DTitel.Titel.Sammelband::d_Ort_t ) &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_Datierung_t ) ;
" " & DTitel.Titel.Sammelband::d_Datierung_t ) &
Case( not IsEmpty( d_AusgabeSeite_t ) ; ", S. " & d_AusgabeSeite_t )&
Case( not IsEmpty( DTitel.Titel.Sammelband::_fk_sammelband_t );
/* Ein Ausatz in Sammelband als Teil einer Werkausgabe */
" [" & Trim( DTitel.Titel.SB.Werkausgabe::d_Kurztitel_t &
Case( not isempty( DTitel.Titel.Sammelband::d_AusgabeVol_t ) ;", Bd. " & DTitel.Titel.Sammelband::d_AusgabeVol_t ) &
Case(not IsEmpty( DTitel.Titel.Sammelband::d_AusgabeVol_t ) and not IsEmpty( DTitel.Titel.Sammelband::d_AusgabeNr_t ) ; " Nr. ";
not isempty( DTitel.Titel.Sammelband::d_AusgabeNr_t ) ; ", Nr. ") &
DTitel.Titel.Sammelband::d_AusgabeNr_t)
& "]"
) //end case
) // End trim
;
d_Datentyp2_t = "Vortrag";

// Zitform für Vorträge

Trim(
$Autor &
": " & """ & d_Titel_t & """ & ", Vortrag, " &
""" & DTitel.Titel.Sammelband::d_Titel_t & "", " &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_Ort_t ); DTitel.Titel.Sammelband::d_Ort_t ) &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_Datierung_t ) ; " " &
DTitel.Titel.Sammelband::d_Datierung_t )
) // End trim
;
d_Datentyp2_t = "Tagung";

// Zitform für Tagungen

Trim(
"Tagung " &
" " & """ & d_Titel_t & """ & "" &
Case( not IsEmpty( d_Körperschaft_t ); ", " & d_Körperschaft_t ) &
Case( not IsEmpty( d_Ort_t ) ; ", " & d_Ort_t ) &
Case( not IsEmpty( d_Datierung_t ) ; ", " & d_Datierung_t )
) // End trim
;

// Zitform für Monographien und den Rest

Trim(
$Autor &
": " & d_Titel_t & ", " &
Case( $HerausgeberStatus = 3 ; "hg. v. " & d_HerausgeberName_t & ", "; $HerausgeberStatus = 4 ; "hg. v. " & d_Körperschaft_t & ", ") &
Case( not IsEmpty( d_Ort_t ); d_Ort_t ) &
Case( not IsEmpty( d_Datierung_t ) ; " " & d_Datierung_t ) &
/* Jetzt folgen die Abfragen von Auflage, Bibl. Zusätze und Reihe */

Case( not IsEmpty( d_Auflage_t ) and IsEmpty( d_BibliogrZusätze_t) and IsEmpty( d_Reihe_t ); " (" & d_Auflage_t & ") " ) &

Case( not IsEmpty( d_Auflage_t ) and not IsEmpty( d_BibliogrZusätze_t) and IsEmpty( d_Reihe_t ); " (" & d_Auflage_t & "; " & d_BibliogrZusätze_t & ") ") &

Case( not IsEmpty( d_Auflage_t ) and not IsEmpty( d_BibliogrZusätze_t) and not IsEmpty( d_Reihe_t ); " (" & d_Auflage_t & "; " & d_BibliogrZusätze_t & ") " & " [" & d_Reihe_t & "]") &

Case( IsEmpty( d_Auflage_t ) and not IsEmpty( d_BibliogrZusätze_t) and IsEmpty( d_Reihe_t ); " (" & d_BibliogrZusätze_t & ")") &

Case( IsEmpty( d_Auflage_t ) and not IsEmpty( d_BibliogrZusätze_t) and not IsEmpty( d_Reihe_t ); " (" & d_BibliogrZusätze_t & ") " & "[" & d_Reihe_t & "]") &

Case( IsEmpty( d_Auflage_t ) and IsEmpty( d_BibliogrZusätze_t) and not IsEmpty( d_Reihe_t ); " (" & d_Reihe_t & ")") &

Case( not IsEmpty( d_Auflage_t ) and IsEmpty( d_BibliogrZusätze_t) and not IsEmpty( d_Reihe_t ); " (" & d_Auflage_t & ")" & " [" & d_Reihe_t & "]") &
Case( not IsEmpty( DTitel.Titel.Sammelband::_pk_GUID );

" [" & Trim( DTitel.Titel.Sammelband::d_Kurztitel_t &
Case( not isempty( d_AusgabeVol_t ) ;", Bd. " & d_AusgabeVol_t ) &
Case(not IsEmpty( d_AusgabeVol_t ) and not IsEmpty(d_AusgabeNr_t) ; " Nr. ";
not isempty(d_AusgabeNr_t) ; ", Nr. ") &
d_AusgabeNr_t)
& "]"
) //end case
) // End trim
) //End Case

& DGlobals::v_ZitFormSchlusszeichen_tg
)

Zurück