//Basti 2007
//Überarbeitet N. Busch 30.04.2009
Let(
[$Periodikum =
Case( DGlobals::d_SigleBenutzen_n = 1 and not IsEmpty( DTitel.Periodikum::d_Sigle_t );
DTitel.Periodikum::d_Sigle_t;
DTitel.Periodikum::d_Titel_t );
$HerausgeberStatus =
Case( IsEmpty( d_HerausgeberName_t) and d_Herausgeber_n <> 1 ; 0;
IsEmpty( d_HerausgeberName_t) and d_Herausgeber_n = 1 ; 1 ;
not IsEmpty( d_HerausgeberName_t) and IsEmpty(d_AutorNachname_t); 2;
not IsEmpty( d_HerausgeberName_t) and not IsEmpty(d_AutorNachname_t); 3) ;
$AutorPerson =
Trim( d_AutorNachname_t & Case( not IsEmpty( d_AutorVorname_t ) ; ", " &
d_AutorVorname_t ) & xcalc_Pseudonym_ctu ) ;
$Coautoren =
Trim(Case(
not IsEmpty( xCalc_NamenCoautorenNV_ctu) ;
DGlobals::d_Coautortrenner_t & xCalc_NamenCoautorenNV_ctu ;
not IsEmpty( d_CoAutoren_t ) ;
", " & d_CoAutoren_t
)) ;
$CoautorenSB =
Trim(Case(
not IsEmpty( DTitel.Titel.Sammelband::xCalc_NamenCoautorenNV_ctu) ;
DGlobals::d_Coautortrenner_t & DTitel.Titel.Sammelband::xCalc_NamenCoautorenNV_ctu ;
not IsEmpty( DTitel.Titel.Sammelband::d_CoAutoren_t ) ;
", " & DTitel.Titel.Sammelband::d_CoAutoren_t
));
$Autor =
Case(
$Herausgeberstatus = 0;
$Autorperson &
$Coautoren;
$Herausgeberstatus = 1;
$Autorperson &
$Coautoren &
" (" & DGlobals::d_HerausgeberKürzel_t & ")" ;
$Herausgeberstatus = 2;
d_HerausgeberName_t & " (" & DGlobals::d_HerausgeberKürzel_t & ")" ;
$Herausgeberstatus = 3;
$Autorperson &
$Coautoren
;
) // end case
]
;
Case(
d_Datentyp2_t = "Artikel";
// Zitform für Artikel
Trim(
$Autor &
Case(not IsEmpty(d_Datierung_t) ; " (" & d_Datierung_t & ")" ) &
": "" & d_Titel_t & "." In: " &
TextStyleAdd( $Periodikum ; Italic ) &
Case( not IsEmpty( d_AusgabeNr_t ); " " & d_AusgabeNr_t ) &
Case( not IsEmpty( d_AusgabeSeite_t) ; ": " & d_AusgabeSeite_t ) & "."
) // End trim
;
d_Datentyp2_t = "Aufsatz";
// Zitform für Aufsätze
Trim(
$Autor &
Case(not IsEmpty(d_Datierung_t) ; " (" & d_Datierung_t & "):") &
" "" & d_Titel_t & "." In: " &
Trim( DTitel.Titel.Sammelband::d_AutorNachname_t & ", " & DTitel.Titel.Sammelband::d_AutorVorname_t ) & " " &
Case ( IsEmpty( DTitel.Titel.Sammelband::d_CoAutoren_t ) ; "(ed.), ") &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_CoAutoren_t ) ; "/ " & DTitel.Titel.Sammelband::d_CoAutoren_t & " (edd.), " ) &
Trim (TextStyleAdd( DTitel.Titel.Sammelband::d_Titel_t ; Italic ) & ", ") & " " &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_Ort_t ); DTitel.Titel.Sammelband::d_Ort_t ) &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_Ort_t ) and not IsEmpty( DTitel.Titel.Sammelband::d_Verlag_t ) ; ": ") &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_Verlag_t ) ; DTitel.Titel.Sammelband::d_Verlag_t ) &
Case( not IsEmpty( d_AusgabeSeite_t ) ; ", " & d_AusgabeSeite_t ) & "."&
Case( not IsEmpty( DTitel.Titel.Sammelband::_fk_sammelband_t );
/* Ein Ausatz in Sammelband als Teil einer Werkausgabe */
" [" & Trim( DTitel.Titel.SB.Werkausgabe::d_Kurztitel_t & " " & DTitel.Titel.Sammelband::d_AusgabeVol_t &
Case(
not IsEmpty( DTitel.Titel.Sammelband::d_AusgabeVol_t ) and not IsEmpty( DTitel.Titel.Sammelband::d_AusgabeNr_t) ;
"/") & DTitel.Titel.Sammelband::d_AusgabeNr_t
)
& "]"
) //end case
) // End trim
;
d_Datentyp2_t = "Vortrag";
// Zitform für Vorträge
Trim(
$Autor &
": " & Quote( d_Titel_t ) & ", Vortrag, " &
"" & Quote( DTitel.Titel.Sammelband::d_Titel_t ) & ", " &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_Ort_t ); DTitel.Titel.Sammelband::d_Ort_t ) &
Case( not IsEmpty( DTitel.Titel.Sammelband::d_Datierung_t ) ; " " & DTitel.Titel.Sammelband::d_Datierung_t )
) // End trim
;
d_Datentyp2_t = "Tagung";
// Zitform für Tagungen
Trim(
"Tagung " &
" " & Quote( d_Titel_t ) & "" &
Case( not IsEmpty( d_Körperschaft_t ); ", " & d_Körperschaft_t ) &
Case( not IsEmpty( d_Ort_t ) ; ", " & d_Ort_t ) &
Case( not IsEmpty( d_Datierung_t ) ; ", " & d_Datierung_t )
) // End trim
;
// Zitform für Monographien
Trim(
$Autor &
Case(not ( IsEmpty(d_Datierung_t) and isempty( d_auflage_t)) ; " (" & case(not isempty( d_auflage_t ) ; d_auflage_t & ". Aufl. " ) & d_Datierung_t & ")") &
": " & TextStyleAdd( d_Titel_t ; Italic) &
Case( not IsEmpty( d_Ort_t ) and not IsEmpty( d_Verlag_t ) ; ". ") &
Case ( IsEmpty( d_Verlag_t ) ; ". ") &
Case( not IsEmpty( d_Ort_t ); d_Ort_t ) &
Case( not IsEmpty( d_Verlag_t ) ; ": " & d_Verlag_t ) &
Case( not IsEmpty( d_BibliogrZusätze_t ) ; " (" & d_BibliogrZusätze_t & ")") & "." &
Case( not IsEmpty( DTitel.Titel.Sammelband::_pk_GUID );
" [" & Trim( DTitel.Titel.Sammelband::d_Kurztitel_t &
Case( not isempty( d_AusgabeVol_t ) ;", Bd. " & d_AusgabeVol_t ) &
Case(not IsEmpty( d_AusgabeVol_t ) and not IsEmpty(d_AusgabeNr_t) ; " Nr. ";
not isempty(d_AusgabeNr_t) ; ", Nr. ") &
d_AusgabeNr_t)
& "]"
) //end case
) // End trim
) //End Case
& DGlobals::v_ZitFormSchlusszeichen
)